*************************************************************************;
*   PROGRAM NAME: ReadinData.sas                                        *;
*   DATE CREATED: 09/23/03                                              *;
*   LAST UPDATED: 10/27/03                                              *;
*                                                                       *;
*    PROGRAMMERS: NYC DOHMH Bureau of Communicable Disease              *;
*        PURPOSE: Sample program reads in data from 4 file types and    *;
*                 transforms into standard format                       *;
************************************************************************;

* We've found these options to be useful;
options ls=120                    /*Wide page less likely to wrap output*/
        ps=5000                   /*Long page-size less likely to split up a table*/
        nodate                    /*Suppresses date at top of page in output*/
        nocenter                  /*Left-justifies output*/
		nonumber                  /*Suppresses page number in output*/
		yearcutoff=1920
		formdlim='-'	          /*Saves paper, no page return between procedure output*/
;

* Create a SAS library name for data folder;  
libname data "c:\SyndromicWorkshop\sas\data";

* Create macro for data folder.  If you want to put data in a different location you only have 
  to change this line and all macro references throughout the program will be changeed; 
%LET FOLDER=c:\SyndromicWorkshop\sas\data;


*ED1: Report format;
data readED1;
 attrib cc length=$50.;  
 infile "&FOLDER\ED1_072503.txt" lrecl=100 pad; *YOU NEED THE DOUBLE QUOTES IF USING MACRO!!!!;
 input    @2  id      $11.
   @14 age      $3.
   @19 sex      $1.
   @23 zip      $5.
   @29 cc2      $30.
   @60 mode     $3.
   @66 datetxt  $8.
   @75 time     $5.;
 EDcode='ED1';
 if id ^=: 'XX' then delete;
 cc=cc2;  drop cc2;
run;


*ED2: Two EDs in same file, AM/PM;
data readED2;
 infile "&FOLDER\ED2_072503.txt" lrecl=100 pad;    
 attrib time length=$5. 
          id length=$15.;
 input  @1  EDcode1  $1.
        @2  datetxt  $8.
       @10  hour      2.
       @13  minute   $2.
       @15  AMPM     $1.
       @17  age      $3.
       @21  sex      $1.
       @22  cc      $50.
       @72  zip      $5.;
 yr=substr(datetxt,7,2)*1; drop yr;
 if 0<yr<9;
   IF EDcode1="A" THEN EDcode="ED2";  
     ELSE if EDcode1="B" then EDcode="ED2B";
   IF AMPM="P" and hour ne "12"  THEN HOUR=HOUR+12;
    hour2=put(hour,z2.);
    TIME=HOUR2 || ":" || MINUTE; DROP HOUR MINUTE EDcode1 AMPM HOUR2;
run;


*ED3: Date is in the header, report format with lots of extra lines and fields; 
data readED3;
infile "&FOLDER\ED3_072503.txt" lrecl=130 pad; retain datetxt;
attrib datetxt length=$7.;
if _n_=1 then do;
  inDT: input / @9 datetxt1 $7. @;
  if datetxt1 ne 'D A T E' then goto inDT;
  if datetxt1 = 'D A T E' then do; 
     input @34 datetxt $8. @; 
  end; drop datetxt1;
end;
input
        @3  id           $6.
        @44 time         $5.
        @56 age          $2.
        @61 sex          $1.
        @63 zip          $5.
        @81 cc2          $31.;
  EDcode='ED3';
  if '000001'<=id<='999999';
  ATTRIB CC LENGTH=$50.; CC=CC2; DROP CC2;
run;

*ED4: Excel file  NOTE: This only works if you have the SAS Excel import facility; 
PROC IMPORT OUT= WORK.ED4
            DATAFILE= "&FOLDER\ED4_072503.xls" 
            DBMS=EXCEL2000 REPLACE;
     GETNAMES=NO;
RUN;
data readed4;
  attrib datetxt            length=$8.     format=$8.          label='Date first documented in ED'
         edcode             length=$3.     format=$3.          label='ED code'
         time               length=$5.     format=$5.          label='Time first documented in ED'
         age                length=$3.     format=$3.          label='Age of patient in years'
         sex                length=$1.     format=$1.          label='Sex of patient (M,F,U)'
         zip                length=$5.     format=$5.          label='Patient home zipcode'
         cc                 length=$50.    format=$50.         label='Patient chief complaint'
         id                 length=$15.    format=$15.         label='Internal patient ID'
         DT_stamp           length=8.      format=datetime13.  label='Datetime added to archive'
         ;
 set ed4; 
 datetxt=put(datepart(f1),mmddyy8.);
 edcode='ED4';
   hour=substr(f2,1,2)*1;
   IF substr(f2,6,1)="P" and hour ^= 12 THEN HOUR=hour+12;
    hour2=put(hour,z2.);
    TIME=HOUR2 || ":" || substr(f2,4,2); DROP HOUR hour2;
 age=f3;
 sex=f4;
 cc=f5;
 zip=put(f6,5.);
 DT_stamp=datetime();
 drop f1-f6;
 *if date^=.; 
run;



* Concatenate individual ED datasets into one large dataset. 
  Includes some records with data errors that will be removed by ErrorCheckDedupeAppend.sas;
data readall;
  attrib date               length=8.      format=mmddyy8.     label='Date first documented in ED'
         edcode             length=$3.     format=$3.          label='ED code'
         time               length=$5.     format=$5.          label='Time first documented in ED'
         age                length=$3.     format=$3.          label='Age of patient in years'
         sex                length=$1.     format=$1.          label='Sex of patient (M,F,U)'
         zip                length=$5.     format=$5.          label='Patient home zipcode'
         cc                 length=$50.    format=$50.         label='Patient chief complaint'
         id                 length=$15.    format=$15.         label='Internal patient ID'
         DT_stamp           length=8.      format=datetime13.  label='Datetime added to archive'
         ;

  keep date edcode time age sex zip cc id DT_stamp;
  set
     readed1
	 readed2
	 readed3
	 readed4
  ;

     date=input(datetxt,mmddyy8.);
     DT_stamp=datetime();  

run;


* Other fields that are received from a small proportion of NYC EDs and are not used in analysis
         mode               length=$5.     format=$5.          label='Mode of transport to ED'
		 ddcode             length=$50.    format=$50.         label='ED disposition diagnosis code'
		 dd                 length=$50.    format=$50.         label='ED disposition diagnosis description'
         chest_Xray         length=$3.     format=$3.          label='Chest x-ray ordered'
         blood_gas          length=$3.     format=$3.          label='Arterial blood gas ordered'
         wbc                length=$7.     format=$7.          label='Total white blood cell count'
         max_temp           length=5.1     format=5.1          label='Patient maximum temperature'          
;